10 CLEAR:COLOR 0,3,1:CLS
20 PRINT "               ÉÍËÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍËÍ»"
30 PRINT "               ÌÍÎÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÎ͹"
40 PRINT "               º º                                            º º"
50 PRINT "               º º                                            º º"
60 PRINT "               º º          WELCOME TO TEN THOUSAND!!         º º"
70 PRINT "               º º                                            º º"
80 PRINT "               º º         PROGRAM WRITTEN BY DAN BUCK        º º"
90 PRINT "               º º                                            º º"
100 PRINT"               º º                                            º º"
110 PRINT"               ÌÍÎÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÎ͹"
120 PRINT"               ÈÍÊÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÊͼ"
130 PRINT:PRINT:INPUT"PLEASE ENTER THE NUMBER OF PLAYERS: ",P
140 IF P<1 OR P>20 THEN PRINT"Your input is invalid. Please choose between 1 and 20 players.":GOTO 130
150 DIM A$(P):DIM D(5):DIM E(5)
160 FOR X=1 TO P
170 PRINT"WHAT IS YOUR NAME PLAYER #"X;:INPUT A$(X)
180 NEXT X
190 PRINT:PRINT:PRINT"PRESS ANY KEY TO BEGIN."
200 I$=INKEY$:IF I$="" THEN 200
210 CLS:DIM A(P):RANDOMIZE(TIMER)
220 RO=RO+1
225 COLOR 1
230 FOR X=1 TO P
240 S=0:TS=0:CLS:N=5:PRINT"PLAYER #"X,,A$(X),,"SCORE: "A(X)
250 FOR Y=1 TO N:D(Y)=INT(RND*6)+1:E(Y)=D(Y):NEXT Y
260 FOR Y=1 TO 3
270 FOR ZZ=1 TO N
280 ON Y GOTO 281,282,283
281 ON D(ZZ) GOSUB 1020,1030,1030,1060,1060,1060:GOTO 290
282 ON D(ZZ) GOSUB 1040,1020,1040,1020,1040,1060:GOTO 290
283 ON D(ZZ) GOSUB 1020,1050,1050,1060,1060,1060:GOTO 290
290 IF ZZ=N THEN PRINT
295 NEXT ZZ
300 NEXT Y
310 REM
320 PRINT:TN=N
325 COLOR 1
330 TN=TN-1
340 FOR Y=1 TO TN
350 IF E(Y)>E(Y+1) THEN TV=E(Y):E(Y)=E(Y+1):E(Y+1)=TV
360 NEXT Y
370 IF TN<>0 THEN 330
380 IF N<>5 THEN 400
390 IF E(1)=E(2) AND E(2)=E(3) AND E(3)=E(4) AND E(4)=E(5) THEN VS=VS+E(1)*1000:N=N-5:GOTO 460
400 IF N<3 THEN 480
410 IF E(1)=E(2) AND E(2)=E(3) THEN VS=E(3)*100:N=N-3:E(1)=E(4):E(2)=E(5):GOTO 460
420 IF N<4 THEN 480
430 IF E(2)=E(3) AND E(3)=E(4) THEN VS=E(3)*100:N=N-3:E(2)=E(5):GOTO 460
440 IF N<5 THEN 480
450 IF E(3)=E(4) AND E(4)=E(5) THEN VS=E(3)*100:N=N-3
460 IF E(3)=1 THEN VS=VS*10
470 TS=TS+VS:VS=0
480 FOR Y=1 TO N
490 IF E(Y)=1 THEN TS=TS+100:N=N-1
500 IF E(Y)=5 THEN TS=TS+50:N=N-1
510 NEXT Y
520 IF S=TS THEN PRINT"YOU LOSE YOUR ROLL":GOTO 610
530 PRINT"SCORE: "TS
540 IF N<>0 AND A(X)<500 AND TS<500 THEN PRINT"PRESS `R' TO ROLL":GOTO 570
550 IF N<>0 THEN PRINT"DO YOU WISH TO ROLL(R) OR KEEP(K)"
560 IF N=0 THEN N=5:PRINT TS" AND ALL THE DICE":S=TS:INPUT"PRESS <ENTER> TO CONTINUE.",Z$:GOTO 250
570 Q$=INKEY$
580 IF (Q$="K" OR Q$="k") AND (A(X)>499 OR TS>499) THEN A(X)=A(X)+TS:IF A(X)>=10000 THEN 680 ELSE 610
590 IF Q$="R" OR Q$="r"THEN S=TS:GOTO 250
595 IF Q$="Q" OR Q$="q" THEN INPUT"REALLY QUIT? (Y/N)";Q2$:IF Q2$="y" OR Q2$="Y" THEN 720 ELSE PRINT"GAME CONTINUES...FOLLOW ABOVE INSTRUCTIONS FOR ROLL AND KEEP."
596 IF Q$="S" OR Q$="s" THEN INPUT"REALLY START WITH 500? (Y/N)";Q2$:IF Q2$="y" OR Q2$="Y" THEN A(X)=500:PRINT"STARTING THE GAME WITH 500.":GOTO 610 ELSE PRINT"GAME CONTINUES...FOLLOW ABOVE INSTRUCTIONS FOR ROLL AND KEEP."
597 IF Q$<>"" THEN TQ=ASC(Q$)-48:IF TQ<P+1 AND TQ>0 THEN PRINT"PLAYER #"TQ", "A$(TQ)", HAS"A(TQ)"POINTS."
600 GOTO 570
610 PRINT"PRESS ANY KEY TO CONTINUE"
620 I$=INKEY$:IF I$=""THEN 620
630 NEXT X
640 GOTO 220
650 LIST
660 END
670 FOR X=1 TO 254:PRINT CHR$(X)" "X;:NEXT X:END
680 COLOR 0:PRINT:PRINT"THAT BRINGS YOUR SCORE TO"A(X)
685 COLOR 20:PRINT A$(X)" IS THE WINNER!":COLOR 0
690 PRINT"YOU WON THE GAME IN"RO"ROLLS."
700 PRINT"PRESS `M' TO RETURN TO THE MAIN MENU."
710 I$=INKEY$:IF I$<>"M" AND I$<>"m"THEN 710
720 CHAIN"MENU"
1010 END
1020 GOSUB 1160:GOTO 1080
1030 GOSUB 1120:GOSUB 1110:GOSUB 1150:GOTO 1080
1040 GOSUB 1140:GOSUB 1110:GOSUB 1140:GOTO 1080
1050 GOSUB 1150:GOSUB 1110:GOSUB 1120:GOTO 1080
1060 GOSUB 1120:GOSUB 1110:GOSUB 1140:GOSUB 1110:GOSUB 1120:GOTO 1080
1080 COLOR 1,3,3:PRINT" ";:RETURN
1090 COLOR 1,3,3:PRINT:RETURN
1100 END
1110 COLOR 0,7,3:PRINT CHR$(254);:RETURN
1120 COLOR 0,7,3:PRINT" ";:RETURN
1130 COLOR 0,7,3:PRINT"  ";:RETURN
1140 COLOR 0,7,3:PRINT"   ";:RETURN
1150 COLOR 0,7,3:PRINT"     ";:RETURN
1160 COLOR 0,7,3:PRINT"       ";:RETURN