:: Cleanup.bat - Locate files X days old as defined by the date flag 
::               file, C:\_dates_.bat.
::               Requires IncrDate.bat and DSearch.Bat.
:: Tom lavedas <lavedas@pressroom.com>
::             http://www.pressroom.com/~tglbatch
 @echo %dbgc% off
  if '%1==' %0 .\
  for %%v in (%1 %1.\nul) do if exist %%v goto Okay
  echo Folder %1 not found
  goto End
 :Okay
  if not exist c:\_dates_.bat goto End
  call c:\_dates_.bat
  echo @prompt if '%%%%2==' %%%%0 $D$_set Today=%%%%2$_ > %temp%.\~tempA.bat
  %comspec%/e:2048/c %temp%.\~tempA.bat > %temp%.\~tempB.bat
  for %%v in (%temp%.\~tempB.bat del) do call %%v %temp%.\~temp?.bat
  if %Yesterday%==%Today% echo Cleanup process already run today (%Today%).
  if %Yesterday%==%Today% goto End
  if not %1==.\ %1.\
  if exist %1      cd %1\..
  if exist %1.\nul cd %1.
 :Loop
  for %%v in (RemoveDate Yesterday) do call IncrDate %%v
  if not %Yesterday%==%Today% goto Loop
  echo echo del %%1 > %temp%.\~process.bat
  call DSearch %RemoveDate% %temp%.\~process.bat
  del %temp%.\~process.bat
  echo set Yesterday=%Yesterday%> c:\_dates_.bat
  echo set RemoveDate=%RemoveDate%>>c:\_dates_.bat
 :End